全新推出：LiteRT：Google 专为设备端 AI 打造的高性能运行时，以前称为 TensorFlow Lite。

此页面由 Cloud Translation API 翻译。

缩减 LiteRT 二进制文件大小

概览

为设备端机器学习 (ODML) 应用部署模型时，请务必注意移动设备可用的内存有限模型二进制文件大小与模型。通过使用 LiteRT，选择性 build。选择性构建会跳过模型集中未使用的操作，并且生成一个紧凑的库，其中只包含要在移动设备上运行的模型。

选择性构建适用于以下三个操作库。

下表显示了选择性 build 对一些常见用途的影响用例：

模型名称	网域	目标架构	AAR 文件大小
Mobilenet_1.0_224(float)	图片分类	armeabi-v7a	tensorflow-lite.aar（296635 字节）
Mobilenet_1.0_224(float)	图片分类	arm64-v8a	tensorflow-lite.aar（382892 字节）
SPICE	音高提取	armeabi-v7a	tensorflow-lite.aar（375813 字节） tensorflow-lite-select-tf-ops.aar（1676380 字节）
SPICE	音高提取	arm64-v8a	tensorflow-lite.aar（421826 字节） tensorflow-lite-select-tf-ops.aar（2298630 字节）
i3d-kinetics-400	视频分类	armeabi-v7a	tensorflow-lite.aar（240085 字节） tensorflow-lite-select-tf-ops.aar（1708597 字节）
i3d-kinetics-400	视频分类	arm64-v8a	tensorflow-lite.aar（273713 字节） tensorflow-lite-select-tf-ops.aar（2339697 字节）

使用 Bazel 选择性地构建 LiteRT

本部分假定您已下载 TensorFlow 源代码，并将促进本地开发环境 Bazel。

为 Android 项目构建 AAR 文件

您可以通过提供模型文件路径来构建自定义 LiteRT AAR ，如下所示。

sh tensorflow/lite/tools/build_aar.sh \
  --input_models=/a/b/model_one.tflite,/c/d/model_two.tflite \
  --target_archs=x86,x86_64,arm64-v8a,armeabi-v7a

上述命令会生成 AAR 文件 bazel-bin/tmp/tensorflow-lite.aar 适用于 LiteRT 内置和自定义操作；并视需要生成文件bazel-bin/tmp/tensorflow-lite-select-tf-ops.aar 选择 TensorFlow 操作。请注意，这样会生成一个“胖”在自动采纳建议时架构；如果您并不需要所有字段，请使用适用于部署环境

使用自定义操作构建

如果您开发了带有自定义操作的 LiteRT 模型，方法是在 build 命令中添加以下标志：

sh tensorflow/lite/tools/build_aar.sh \
  --input_models=/a/b/model_one.tflite,/c/d/model_two.tflite \
  --target_archs=x86,x86_64,arm64-v8a,armeabi-v7a \
  --tflite_custom_ops_srcs=/e/f/file1.cc,/g/h/file2.h \
  --tflite_custom_ops_deps=dep1,dep2

tflite_custom_ops_srcs 标志包含自定义操作的源文件， tflite_custom_ops_deps 标志包含用于构建这些源代码的依赖项文件。请注意，这些依赖项必须存在于 TensorFlow 代码库中。

高级用法：自定义 Bazel 规则

如果您的项目使用 Bazel，并且您想要定义自定义 TFLite 依赖项，您可以在项目代码库：

仅适用于具有内置 op 的模型：

load(
    "@org_tensorflow//tensorflow/lite:build_def.bzl",
    "tflite_custom_android_library",
    "tflite_custom_c_library",
    "tflite_custom_cc_library",
)

# A selectively built TFLite Android library.
tflite_custom_android_library(
    name = "selectively_built_android_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# A selectively built TFLite C library.
tflite_custom_c_library(
    name = "selectively_built_c_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# A selectively built TFLite C++ library.
tflite_custom_cc_library(
    name = "selectively_built_cc_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

对于具有选择 TF 操作的模型：

load(
    "@org_tensorflow//tensorflow/lite/delegates/flex:build_def.bzl",
    "tflite_flex_android_library",
    "tflite_flex_cc_library",
)

# A Select TF ops enabled selectively built TFLite Android library.
tflite_flex_android_library(
    name = "selective_built_tflite_flex_android_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# A Select TF ops enabled selectively built TFLite C++ library.
tflite_flex_cc_library(
    name = "selective_built_tflite_flex_cc_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

高级用途：构建自定义 C/C++ 共享库

如果您想针对则可以按照以下步骤操作：

在根目录下运行以下命令，创建临时 BUILD 文件目录中：

mkdir -p tmp && touch tmp/BUILD

构建自定义 C 共享对象

如果您想构建自定义 TFLite C 共享对象，请将以下内容添加到 tmp/BUILD 文件：

load(
    "//tensorflow/lite:build_def.bzl",
    "tflite_custom_c_library",
    "tflite_cc_shared_object",
)

tflite_custom_c_library(
    name = "selectively_built_c_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# Generates a platform-specific shared library containing the LiteRT C
# API implementation as define in `c_api.h`. The exact output library name
# is platform dependent:
#   - Linux/Android: `libtensorflowlite_c.so`
#   - Mac: `libtensorflowlite_c.dylib`
#   - Windows: `tensorflowlite_c.dll`
tflite_cc_shared_object(
    name = "tensorflowlite_c",
    linkopts = select({
        "//tensorflow:ios": [
            "-Wl,-exported_symbols_list,$(location //tensorflow/lite/c:exported_symbols.lds)",
        ],
        "//tensorflow:macos": [
            "-Wl,-exported_symbols_list,$(location //tensorflow/lite/c:exported_symbols.lds)",
        ],
        "//tensorflow:windows": [],
        "//conditions:default": [
            "-z defs",
            "-Wl,--version-script,$(location //tensorflow/lite/c:version_script.lds)",
        ],
    }),
    per_os_targets = True,
    deps = [
        ":selectively_built_c_lib",
        "//tensorflow/lite/c:exported_symbols.lds",
        "//tensorflow/lite/c:version_script.lds",
    ],
)

新添加的目标可以按如下方式构建：

bazel build -c opt --cxxopt=--std=c++17 \
  //tmp:tensorflowlite_c

对于 Android（针对 64 位，请将 android_arm 替换为 android_arm64）：

bazel build -c opt --cxxopt=--std=c++17 --config=android_arm \
  //tmp:tensorflowlite_c

构建自定义 C++ 共享对象

如果要构建自定义 TFLite C++ 共享对象，请添加以下内容 tmp/BUILD 文件：

load(
    "//tensorflow/lite:build_def.bzl",
    "tflite_custom_cc_library",
    "tflite_cc_shared_object",
)

tflite_custom_cc_library(
    name = "selectively_built_cc_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# Shared lib target for convenience, pulls in the core runtime and builtin ops.
# Note: This target is not yet finalized, and the exact set of exported (C/C++)
# APIs is subject to change. The output library name is platform dependent:
#   - Linux/Android: `libtensorflowlite.so`
#   - Mac: `libtensorflowlite.dylib`
#   - Windows: `tensorflowlite.dll`
tflite_cc_shared_object(
    name = "tensorflowlite",
    # Until we have more granular symbol export for the C++ API on Windows,
    # export all symbols.
    features = ["windows_export_all_symbols"],
    linkopts = select({
        "//tensorflow:macos": [
            "-Wl,-exported_symbols_list,$(location //tensorflow/lite:tflite_exported_symbols.lds)",
        ],
        "//tensorflow:windows": [],
        "//conditions:default": [
            "-Wl,-z,defs",
            "-Wl,--version-script,$(location //tensorflow/lite:tflite_version_script.lds)",
        ],
    }),
    per_os_targets = True,
    deps = [
        ":selectively_built_cc_lib",
        "//tensorflow/lite:tflite_exported_symbols.lds",
        "//tensorflow/lite:tflite_version_script.lds",
    ],
)

新添加的目标可以按如下方式构建：

bazel build -c opt  --cxxopt=--std=c++17 \
  //tmp:tensorflowlite

对于 Android（针对 64 位，请将 android_arm 替换为 android_arm64）：

bazel build -c opt --cxxopt=--std=c++17 --config=android_arm \
  //tmp:tensorflowlite

对于具有选择 TF 操作的模型，您还需要构建以下共享库：

load(
    "@org_tensorflow//tensorflow/lite/delegates/flex:build_def.bzl",
    "tflite_flex_shared_library"
)

# Shared lib target for convenience, pulls in the standard set of TensorFlow
# ops and kernels. The output library name is platform dependent:
#   - Linux/Android: `libtensorflowlite_flex.so`
#   - Mac: `libtensorflowlite_flex.dylib`
#   - Windows: `libtensorflowlite_flex.dll`
tflite_flex_shared_library(
  name = "tensorflowlite_flex",
  models = [
      ":model_one.tflite",
      ":model_two.tflite",
  ],
)

新添加的目标可以按如下方式构建：

bazel build -c opt --cxxopt='--std=c++17' \
      --config=monolithic \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain \
      //tmp:tensorflowlite_flex

对于 Android（针对 64 位，请将 android_arm 替换为 android_arm64）：

bazel build -c opt --cxxopt='--std=c++17' \
      --config=android_arm \
      --config=monolithic \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain \
      //tmp:tensorflowlite_flex

选择性地使用 Docker 构建 LiteRT

本部分假定您已安装本地机器上的 Docker 和下载了 LiteRT Dockerfile 此处。

下载上述 Dockerfile 后，您可以通过以下命令构建 Docker 映像：运行：

docker build . -t tflite-builder -f tflite-android.Dockerfile

为 Android 项目构建 AAR 文件

运行以下命令，下载用于使用 Docker 进行构建的脚本：

curl -o build_aar_with_docker.sh \
  https://raw.githubusercontent.com/tensorflow/tensorflow/master/tensorflow/lite/tools/build_aar_with_docker.sh &&
chmod +x build_aar_with_docker.sh

然后，您可以通过提供模型文件来构建自定义 LiteRT AAR 路径如下。

sh build_aar_with_docker.sh \
  --input_models=/a/b/model_one.tflite,/c/d/model_two.tflite \
  --target_archs=x86,x86_64,arm64-v8a,armeabi-v7a \
  --checkpoint=master \
  [--cache_dir=<path to cache directory>]

checkpoint 标志是一个提交内容、一个分支或 TensorFlow 代码库的标记，您希望在构建库之前结账；默认为 release 分支。上述命令会生成 AAR 文件 tensorflow-lite.aar，适用于 LiteRT 内置和自定义操作，以及可选的用于选择 TensorFlow 操作的 AAR 文件 tensorflow-lite-select-tf-ops.aar 你的当前目录中

--cache_dir 用于指定缓存目录。如果未提供，脚本将在当前工作目录下创建一个名为 bazel-build-cache 的目录，用于缓存。

将 AAR 文件添加到项目

添加 AAR 文件的方法：直接将 AAR 导入到您的项目，或者通过出版将自定义 AAR 部署到本地 Maven 存储库。注意事项您必须将tensorflow-lite-select-tf-ops.aar的 AAR 文件添加为

适用于 iOS 的选择性 build

如需进行设置，请参阅“本地构建”部分设置构建环境并配置 TensorFlow 工作区，指南，了解如何使用构建脚本。