Zmniejsz rozmiar pliku binarnego LiteRT

Przegląd

Podczas wdrażania modeli w aplikacjach wykorzystujących uczenie maszynowe na urządzeniu (ODML) należy pamiętać o ograniczonej ilości pamięci dostępnej na urządzeniach mobilnych. Rozmiary plików binarnych modelu są ściśle powiązane z liczbą operacji używanych w modelu. LiteRT umożliwia zmniejszenie rozmiaru plików binarnych modelu dzięki selektywnym kompilacjom. Kompilacje selektywne pomijają nieużywane operacje w zestawie modeli i tworzą kompaktową bibliotekę zawierającą tylko środowisko wykonawcze i jądra operacji wymagane do uruchomienia modelu na urządzeniu mobilnym.

Selektywne kompilowanie ma zastosowanie do tych 3 bibliotek operacji:

  1. Wbudowana biblioteka operacji LiteRT
  2. Operacje niestandardowe LiteRT
  3. Wybierz bibliotekę operacji TensorFlow

W tabeli poniżej przedstawiamy wpływ selektywnego tworzenia w przypadku niektórych typowych zastosowań:

Nazwa modelu Domena Architektura docelowa Rozmiar pliku AAR
Mobilenet_1.0_224(float) Klasyfikacja obrazów armeabi-v7a tensorflow-lite.aar (296 635 bajtów)
arm64-v8a tensorflow-lite.aar (382 892 bajtów)
SPICE Wyodrębnianie wysokości dźwięku armeabi-v7a tensorflow-lite.aar (375 813 bajtów)
tensorflow-lite-select-tf-ops.aar (1 676 380 bajtów)
arm64-v8a tensorflow-lite.aar (421 826 bajtów)
tensorflow-lite-select-tf-ops.aar (2 298 630 bajtów)
i3d-kinetics-400 Klasyfikacja wideo armeabi-v7a tensorflow-lite.aar (240 085 bajtów)
tensorflow-lite-select-tf-ops.aar (1 708 597 bajtów)
arm64-v8a tensorflow-lite.aar (273 713 bajtów)
tensorflow-lite-select-tf-ops.aar (2 339 697 bajtów)

Selektywne tworzenie LiteRT za pomocą Bazel

W tej sekcji zakładamy, że masz już pobrane kody źródłowe TensorFlow i skonfigurowane lokalne środowisko programistyczne dla Bazela.

Tworzenie plików AAR na potrzeby projektu na Androida

Niestandardowe pliki AAR LiteRT możesz utworzyć, podając ścieżki do plików modelu w ten sposób:

sh tensorflow/lite/tools/build_aar.sh \
  --input_models=/a/b/model_one.tflite,/c/d/model_two.tflite \
  --target_archs=x86,x86_64,arm64-v8a,armeabi-v7a

Powyższe polecenie wygeneruje plik AAR bazel-bin/tmp/tensorflow-lite.aar dla wbudowanych i niestandardowych operacji LiteRT oraz opcjonalnie wygeneruje plik AARbazel-bin/tmp/tensorflow-lite-select-tf-ops.aar, jeśli Twoje modele zawierają operacje Select TensorFlow. Pamiętaj, że w ten sposób tworzysz „gruby” plik AAR z kilkoma różnymi architekturami. Jeśli nie potrzebujesz wszystkich, użyj podzbioru odpowiedniego dla środowiska wdrażania.

Tworzenie z użyciem operacji niestandardowych

Jeśli masz modele LiteRT z niestandardowymi operacjami, możesz je utworzyć, dodając do polecenia kompilacji te flagi:

sh tensorflow/lite/tools/build_aar.sh \
  --input_models=/a/b/model_one.tflite,/c/d/model_two.tflite \
  --target_archs=x86,x86_64,arm64-v8a,armeabi-v7a \
  --tflite_custom_ops_srcs=/e/f/file1.cc,/g/h/file2.h \
  --tflite_custom_ops_deps=dep1,dep2

Flaga tflite_custom_ops_srcs zawiera pliki źródłowe niestandardowych operacji, a flaga tflite_custom_ops_deps zawiera zależności potrzebne do skompilowania tych plików źródłowych. Pamiętaj, że te zależności muszą istnieć w repozytorium TensorFlow.

Zaawansowane zastosowania: niestandardowe reguły Bazel

Jeśli Twój projekt korzysta z Bazel i chcesz zdefiniować niestandardowe zależności TFLite dla danego zestawu modeli, możesz zdefiniować w repozytorium projektu te reguły:

W przypadku modeli z wbudowanymi operacjami:

load(
    "@org_tensorflow//tensorflow/lite:build_def.bzl",
    "tflite_custom_android_library",
    "tflite_custom_c_library",
    "tflite_custom_cc_library",
)

# A selectively built TFLite Android library.
tflite_custom_android_library(
    name = "selectively_built_android_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# A selectively built TFLite C library.
tflite_custom_c_library(
    name = "selectively_built_c_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# A selectively built TFLite C++ library.
tflite_custom_cc_library(
    name = "selectively_built_cc_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

W przypadku modeli z opcją Wybierz operacje TF:

load(
    "@org_tensorflow//tensorflow/lite/delegates/flex:build_def.bzl",
    "tflite_flex_android_library",
    "tflite_flex_cc_library",
)

# A Select TF ops enabled selectively built TFLite Android library.
tflite_flex_android_library(
    name = "selective_built_tflite_flex_android_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# A Select TF ops enabled selectively built TFLite C++ library.
tflite_flex_cc_library(
    name = "selective_built_tflite_flex_cc_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

Zaawansowane zastosowania: tworzenie niestandardowych bibliotek współdzielonych C/C++

Jeśli chcesz utworzyć własne niestandardowe obiekty współdzielone TFLite C/C++ dla podanych modeli, wykonaj te czynności:

Utwórz tymczasowy plik BUILD, uruchamiając to polecenie w katalogu głównym kodu źródłowego TensorFlow:

mkdir -p tmp && touch tmp/BUILD

Tworzenie niestandardowych obiektów udostępnionych w C

Jeśli chcesz utworzyć niestandardowy obiekt współdzielony TFLite C, dodaj do pliku tmp/BUILD ten kod:

load(
    "//tensorflow/lite:build_def.bzl",
    "tflite_custom_c_library",
    "tflite_cc_shared_object",
)

tflite_custom_c_library(
    name = "selectively_built_c_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# Generates a platform-specific shared library containing the LiteRT C
# API implementation as define in `c_api.h`. The exact output library name
# is platform dependent:
#   - Linux/Android: `libtensorflowlite_c.so`
#   - Mac: `libtensorflowlite_c.dylib`
#   - Windows: `tensorflowlite_c.dll`
tflite_cc_shared_object(
    name = "tensorflowlite_c",
    linkopts = select({
        "//tensorflow:ios": [
            "-Wl,-exported_symbols_list,$(location //tensorflow/lite/c:exported_symbols.lds)",
        ],
        "//tensorflow:macos": [
            "-Wl,-exported_symbols_list,$(location //tensorflow/lite/c:exported_symbols.lds)",
        ],
        "//tensorflow:windows": [],
        "//conditions:default": [
            "-z defs",
            "-Wl,--version-script,$(location //tensorflow/lite/c:version_script.lds)",
        ],
    }),
    per_os_targets = True,
    deps = [
        ":selectively_built_c_lib",
        "//tensorflow/lite/c:exported_symbols.lds",
        "//tensorflow/lite/c:version_script.lds",
    ],
)

Nowo dodany cel można utworzyć w ten sposób:

bazel build -c opt --cxxopt=--std=c++17 \
  //tmp:tensorflowlite_c

i na Androida (zastąp android_arm ciągiem android_arm64 w przypadku wersji 64-bitowej):

bazel build -c opt --cxxopt=--std=c++17 --config=android_arm \
  //tmp:tensorflowlite_c

Tworzenie niestandardowych obiektów współdzielonych C++

Jeśli chcesz utworzyć niestandardowy obiekt współdzielony TFLite C++, dodaj do pliku tmp/BUILD ten kod:

load(
    "//tensorflow/lite:build_def.bzl",
    "tflite_custom_cc_library",
    "tflite_cc_shared_object",
)

tflite_custom_cc_library(
    name = "selectively_built_cc_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# Shared lib target for convenience, pulls in the core runtime and builtin ops.
# Note: This target is not yet finalized, and the exact set of exported (C/C++)
# APIs is subject to change. The output library name is platform dependent:
#   - Linux/Android: `libtensorflowlite.so`
#   - Mac: `libtensorflowlite.dylib`
#   - Windows: `tensorflowlite.dll`
tflite_cc_shared_object(
    name = "tensorflowlite",
    # Until we have more granular symbol export for the C++ API on Windows,
    # export all symbols.
    features = ["windows_export_all_symbols"],
    linkopts = select({
        "//tensorflow:macos": [
            "-Wl,-exported_symbols_list,$(location //tensorflow/lite:tflite_exported_symbols.lds)",
        ],
        "//tensorflow:windows": [],
        "//conditions:default": [
            "-Wl,-z,defs",
            "-Wl,--version-script,$(location //tensorflow/lite:tflite_version_script.lds)",
        ],
    }),
    per_os_targets = True,
    deps = [
        ":selectively_built_cc_lib",
        "//tensorflow/lite:tflite_exported_symbols.lds",
        "//tensorflow/lite:tflite_version_script.lds",
    ],
)

Nowo dodany cel można utworzyć w ten sposób:

bazel build -c opt  --cxxopt=--std=c++17 \
  //tmp:tensorflowlite

i na Androida (zastąp android_arm ciągiem android_arm64 w przypadku wersji 64-bitowej):

bazel build -c opt --cxxopt=--std=c++17 --config=android_arm \
  //tmp:tensorflowlite

W przypadku modeli z opcjami Wybierz operacje TF musisz też utworzyć tę bibliotekę współdzieloną:

load(
    "@org_tensorflow//tensorflow/lite/delegates/flex:build_def.bzl",
    "tflite_flex_shared_library"
)

# Shared lib target for convenience, pulls in the standard set of TensorFlow
# ops and kernels. The output library name is platform dependent:
#   - Linux/Android: `libtensorflowlite_flex.so`
#   - Mac: `libtensorflowlite_flex.dylib`
#   - Windows: `libtensorflowlite_flex.dll`
tflite_flex_shared_library(
  name = "tensorflowlite_flex",
  models = [
      ":model_one.tflite",
      ":model_two.tflite",
  ],
)

Nowo dodany cel można utworzyć w ten sposób:

bazel build -c opt --cxxopt='--std=c++17' \
      --config=monolithic \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain \
      //tmp:tensorflowlite_flex

i na Androida (zastąp android_arm ciągiem android_arm64 w przypadku wersji 64-bitowej):

bazel build -c opt --cxxopt='--std=c++17' \
      --config=android_arm \
      --config=monolithic \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain \
      //tmp:tensorflowlite_flex

Selektywne tworzenie LiteRT za pomocą Dockera

W tej sekcji zakładamy, że masz zainstalowanego Dockera na komputerze lokalnym i pobrany plik Dockerfile LiteRT tutaj.

Po pobraniu powyższego pliku Dockerfile możesz utworzyć obraz Dockera, uruchamiając to polecenie:

docker build . -t tflite-builder -f tflite-android.Dockerfile

Tworzenie plików AAR na potrzeby projektu na Androida

Pobierz skrypt do kompilacji za pomocą Dockera, uruchamiając to polecenie:

curl -o build_aar_with_docker.sh \
  https://raw.githubusercontent.com/tensorflow/tensorflow/master/tensorflow/lite/tools/build_aar_with_docker.sh &&
chmod +x build_aar_with_docker.sh

Następnie możesz utworzyć niestandardowy plik AAR LiteRT, podając ścieżki do plików modelu w ten sposób:

sh build_aar_with_docker.sh \
  --input_models=/a/b/model_one.tflite,/c/d/model_two.tflite \
  --target_archs=x86,x86_64,arm64-v8a,armeabi-v7a \
  --checkpoint=master \
  [--cache_dir=<path to cache directory>]

Flaga checkpoint to zatwierdzenie, gałąź lub tag repozytorium TensorFlow, które chcesz sprawdzić przed skompilowaniem bibliotek. Domyślnie jest to najnowsza gałąź wersji. Powyższe polecenie wygeneruje plik AAR tensorflow-lite.aar dla wbudowanych i niestandardowych operacji LiteRT oraz opcjonalnie plik AAR tensorflow-lite-select-tf-ops.aar dla wybranych operacji TensorFlow w bieżącym katalogu.

Parametr --cache_dir określa katalog pamięci podręcznej. Jeśli nie zostanie podana, skrypt utworzy w bieżącym katalogu roboczym katalog o nazwie bazel-build-cache na potrzeby buforowania.

Dodawanie plików AAR do projektu

Dodaj pliki AAR, importując je bezpośrednio do projektu lub publikując niestandardowy plik AAR w lokalnym repozytorium Maven. Pamiętaj, że jeśli wygenerujesz pliki AAR dla tensorflow-lite-select-tf-ops.aar, musisz je też dodać.

Selektywne kompilowanie w przypadku iOS

Aby skonfigurować środowisko kompilacji i przestrzeń roboczą TensorFlow, zapoznaj się z sekcją dotyczącą kompilacji lokalnej, a następnie postępuj zgodnie z instrukcjami, aby użyć skryptu kompilacji selektywnej na potrzeby iOS.